# Maintainer: Alexandr Bogomyakov (ultradesu) <ab@hexor.ru>

pkgname=mus-fuse
pkgver=0.7.2
pkgrel=1
pkgdesc="Written safely in Rust, FUSE FS with your own private music library hosted on your server securely."
url="https://github.com/house-of-vanity/mus-fuse.git"
arch=($CARCH)
license=(WTFPL custom)
depends=(openssl fuse)
makedepends=(cargo git)
source=("git+https://github.com/house-of-vanity/$pkgname")
sha512sums=('SKIP')
backup=('etc/mus-fuse.yml')

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --long --tags | awk -F '-' '{print $1}'| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/$pkgname"
  cargo fetch --target $CARCH-unknown-linux-gnu
}

build() {
  cd "$srcdir/$pkgname"
  cargo build --release --frozen --all-targets
}

package() {
  install=mus-fuse.install
  cd "$srcdir/$pkgname"
  install -Dt "$pkgdir/usr/bin" target/release/$pkgname
  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 README.md
  install -Dt "$pkgdir/usr/lib/systemd/system" assets/$pkgname.service
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  mkdir -p "$pkgdir/etc"
  cp -n assets/mus-fuse.yml "$pkgdir/etc/mus-fuse.yml"
}